SAP R/3 форум ABAP консультантов
Russian ABAP Developer's Club

Home - FAQ - Search - Memberlist - Usergroups - Profile - Log in to check your private messages - Register - Log in - English
Blogs - Weblogs News

BAPI_OPPORTUNITY_CREATEMULTI



 
Post new topic   Reply to topic    Russian ABAP Developer's Club Forum Index -> SAP Other
View previous topic :: View next topic  
Author Message
admin
Администратор
Администратор



Joined: 01 Sep 2007
Posts: 1639

PostPosted: Sat Oct 20, 2007 1:21 pm    Post subject: BAPI_OPPORTUNITY_CREATEMULTI Reply with quote

Below is a complete prototype program that exercises the CRM OPPORTUNITY BAPIs. It should run as-is, since no special tables or text-elements are used. I did not use EVERY table parameter available to the BAPIs, but this is a good start.

As I promised, once I got these working - I wanted to post my results. I hope this may be useful and serve as a big relief for the next guy.

Code:

*****************************************************************
* Program Name: ZJRC_CRMBAPI01 (SAP vers 4.7, CRM 4.0)
* :
* Description : Test program for the CRM Opportunity BAPI's.
* :
* : CRM_OPPORTUNITYCRM_BAPI BAPI Implementations:
* : ---------------------------- ---------------------
* : BAPI_OPPORTUNITY_GETDETAILMUL Read Opportunities
* : BAPI_OPPORTUNITY_CREATEMULTI Generate Opportunities
* : BAPI_OPPORTUNITY_CHANGEMULTI Change Opportunities
* : BAPI_OPPORTUNITY_DELETEMULTI Delete Opportunities
* :
* : Once the concepts are proven, a function module will
* : will created for Steven J. Lee to call from his
* : modified CRM opportunity screen.
* :
* Parameters : None
* :
* Called from : SE38/SA38
* :
* Calls to :
* Internal : 1. L_Main() - main body.
* : 2. L_GetGUID() - returns guid based on obj_id #.
* : 3. L_GetOppInfo() - calls BAPI_OPPORTUNITY_GETDETAILMU()
* : 4. L_CreateOpp() - calls BAPI_OPPORTUNITY_CREATEMULTI()
* : 5. L_BldCHeader() - builds header param itab.
* : 6. L_BldCOpp() - builds opportunity param itab.
* : 7. L_BldCOrg() - builds organization param itab.
* : 8. L_BldCCustH() - builds customer_head itab.
* : 9. L_BldCFields() - builds input_fields itab. (Partner too)
* :10. L_LinkOpp() - calls BAPI_OPPORTUNITY_CHANGEMULTI()
* :11. L_CheckOpen() - if order is open, cannot save.
* :12. L_ChangeOpp() - calls BAPI_OPPORTUNITY_CHANGEMULTI()
* :13. L_DeleteOpp - calls BAPI_OPPORTUNITY_DELETEMULTI()
* :14. L_OutPut() - displays guid info and bapi results.
* :15. L_DispSubOpps()- displays linked sub-opp guid info.
* :16. L_ClearITabs() - clears various global itabs.
* :
* External : 1. BAPI_OPPORTUNITY_GETDETAILMUL()
* : 2. BAPI_OPPORTUNITY_CREATEMULTI()
* : 3. BAPI_OPPORTUNITY_CHANGEMULTI()
* : 4. BAPI_OPPORTUNITY_DELETEMULTI()
* : 5. BAPI_TRANSACTION_COMMIT()
* : 6. GUID_CREATE() - not implemented.
* : 7. POPUP_TO_INFORM()
* : 8. POPUP_TO_CONFIRM_STEP()
* : 9. CRM_ORDERADM_H_GUID_GET_OW() - get guid by Obj_Id. (Cuzed problems.)
* :10. GET_FIELDTAB_REMOTE() - get list of fieldnames.
* :
* Coupling : None
* :
* Files used :
* SAP files : 1. CRMD_ORDERADM_H = get guid via Obj_Id directly when function
* : CRM_ORDERADM_H_GUID_GET_OW() cuzed problems.
* I-TABS : 1. Many for bapi's, none for other purposes.
* :
* Returns : None
* :
* Examples : 1. *-- As called from SE38/SA38.
* : ZJRC_CRMBAPI01
* Revision His:
***************
* JRC, 05/25/05 - initial.
***************
REPORT ZJRC_CRMBAPI01.

*-- Constants.
CONSTANTS: NO(1) TYPE C VALUE ' ',
YES(1) TYPE C VALUE 'X'.

*-- INCLUDES:
INCLUDE <ICON>.

*-- Tables
*-- BAPI GET-INFO tables. (Global because I use them here/there to "seed"
* corresponding tables for the CREATE/CHANGE/DELETE bapi's. For example,
* if delete, the header info is the same. However, you must be careful
* because the structures are seldom identical requiring a move-corresponding.)
* !!! NOTE !!! - don't forget to also add any new itabs here to module
* L_ClearITabs at the end of this prg. If not, you may get duplicate
* recs in the itab for each call to L_GetOppInfo().
DATA: ith_GetGUID TYPE TABLE OF BAPIBUS20001_GUID_DIS WITH HEADER LINE,
ith_GetHEADER TYPE TABLE OF BAPIBUS20001_HEADER_DIS WITH HEADER LINE,
ith_MastHeader TYPE TABLE OF BAPIBUS20001_HEADER_DIS WITH HEADER LINE,
ith_GetORG TYPE TABLE OF BAPIBUS20001_ORGMAN_DIS WITH HEADER LINE,
ith_GetPARTNER TYPE TABLE OF BAPIBUS20001_PARTNER_DIS WITH HEADER LINE,
ith_GetOPP TYPE TABLE OF BAPIBUS20001_OPPORTUNITY_DIS WITH HEADER LINE,
ith_GetCustH TYPE TABLE OF BAPIBUS20001_CUSTOMER_H_DIS WITH HEADER LINE,
ith_GetDOCFLOW TYPE TABLE OF BAPIBUS20001_DOC_FLOW_DIS WITH HEADER LINE,
ith_GetReturn TYPE TABLE OF BAPIRET2 WITH HEADER LINE.

*-- BAPI CREATE tables. (Declared global so output can be display at end of report.)
DATA: ith_CreReturn TYPE TABLE OF BAPIRET2 WITH HEADER LINE,
ith_CreSaved TYPE TABLE OF BAPIBUS20001_OBJECT_ID WITH HEADER LINE,
ith_CreCreated TYPE TABLE OF BAPIBUS20001_HEADER_INS WITH HEADER LINE.

*-- BAPI CHANGE tables. (Declared global so output can be display at end of report.)
DATA: ith_ChgReturn TYPE TABLE OF BAPIRET2 WITH HEADER LINE.

*-- BAPI DELETE tables. (Declared global so output can be display at end of report.)
DATA: ith_DelObjs TYPE TABLE OF BAPIBUS20001_OBJECT_ID WITH HEADER LINE,
ith_DelReturn TYPE TABLE OF BAPIRET2 WITH HEADER LINE.

*-- When using a Tab control in conjunction with my "OK/EXIT"
* buttons, I need this to go to the START-OF-SELECTION event
* when the OK button is clicked and controlled from the
* AT SELECTION-SCREEN event.
TABLES: SSCRFIELDS.


*********************[ USER INPUT SCREEN ]**********************
*-----------------[ Selection Screen Title ]-------------------
SELECTION-SCREEN SKIP 1.
SELECTION-SCREEN COMMENT 1(60) T_0Title.
SELECTION-SCREEN SKIP 1.

*-------------------[ START SCRN BLOCK 1 ]---------------------
SELECTION-SCREEN BEGIN OF BLOCK B1 WITH FRAME TITLE T_1Title.
SELECTION-SCREEN BEGIN OF LINE.
* *-- Master CRM key.
SELECTION-SCREEN COMMENT 1(10) T_CRMKey.
PARAMETERS: S_CRMKey(10) TYPE C DEFAULT '369'.
* *-- Display master opportunity info.
SELECTION-SCREEN PUSHBUTTON 25(11) T_OKBut USER-COMMAND OK.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN END OF BLOCK B1.

*-------------------[ START SCRN BLOCK 2 ]---------------------
SELECTION-SCREEN BEGIN OF BLOCK B2 WITH FRAME TITLE T_2Title.
SELECTION-SCREEN BEGIN OF LINE.
* *-- Enter sub-opp key to clone from.
SELECTION-SCREEN COMMENT 1(10) T_SubOp1.
PARAMETERS: S_SubOp1(40) TYPE C DEFAULT '(Cloned from master nnn)' LOWER CASE.
* *-- Add Sub-Opp button.
SELECTION-SCREEN PUSHBUTTON 55(15) T_AddSOP USER-COMMAND ADDSOP.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN END OF BLOCK B2.

*-------------------[ START SCRN BLOCK 3 ]---------------------
SELECTION-SCREEN BEGIN OF BLOCK B3 WITH FRAME TITLE T_3Title.
SELECTION-SCREEN BEGIN OF LINE.
* *-- Enter sub-opp key to link to master.
SELECTION-SCREEN COMMENT 1(10) T_LnkKey.
PARAMETERS: S_LnkKey(10) TYPE C DEFAULT '725'.
* *-- Link Sub-Opp button.
SELECTION-SCREEN PUSHBUTTON 25(15) T_LnkSOP USER-COMMAND LNKSOP.
* *-- Un-Link Sub-Opp button.
SELECTION-SCREEN PUSHBUTTON 45(15) T_ULkSOP USER-COMMAND ULKSOP.
* *-- Delete Sub-Opp button.
SELECTION-SCREEN PUSHBUTTON 65(15) T_DELSOP USER-COMMAND DELSOP.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN END OF BLOCK B3.

*-----------------[ OK/EXIT ]-------------------
*-- Ok/Exit pushbuttons. (Actually, OK is DISPLAY above.)
SELECTION-SCREEN SKIP 2.
SELECTION-SCREEN PUSHBUTTON 40(11) T_EXBut USER-COMMAND EXIT.

*-----------------[ INFORMATION ]-------------------
SELECTION-SCREEN SKIP 1.

*-- Set Break point(s).
SELECTION-SCREEN SKIP 1.
SELECTION-SCREEN BEGIN OF LINE.
PARAMETERS: S_Break AS CHECKBOX DEFAULT ' ' MODIF ID BUG.
SELECTION-SCREEN COMMENT 3(31) T_BugTxt MODIF ID BUG.
SELECTION-SCREEN END OF LINE.


*********************[ INITIALIZATION ]**********************
INITIALIZATION.
*-- Global vars.
DATA: g_Ok(1) TYPE C VALUE YES,
g_RunWhat(10) TYPE C,
g_MastGuid TYPE GUID_32,
g_BlankGuid TYPE GUID_32 VALUE '00000000000000000000000000000000',
g_LogicalKey1(4) TYPE N VALUE '0001'.

*-- Screen elements.
* *-- Title
CONCATENATE SY-REPID '-' 'CRM BAPI OPPORTUNITY TEST01'
INTO T_0Title SEPARATED BY SPACE.
T_1Title = 'Master Opportunity'.

* *-- Block1 selections.
T_CRMKey = 'CRM Key:'.

* *-- Block2 selections.
T_2Title = 'Create Opp'.
T_AddSOP = 'Clone Opp'.
T_SubOp1 = 'Desc 2:'.

* *-- Block3 selections.
T_3Title = 'Link/Delete Opp'.
T_LnkKey = 'Link Key:'.
T_LnkSOP = 'Link SubOpp'.
T_ULkSOP = 'UnLink SubOpp'.
T_DelSOP = 'Delete SubOpp'.

* *-- Ok/Exit
* T_OKBut = '@15@Ok'.
T_OKBut = 'Display'.
T_EXBut = '@2O@Exit'.
T_BugTxt = 'Activate break points.'.

* GET PARAMETER ID 'MGU' FIELD S_MGuid.

*********************[ AT SELECTION-SCREEN ]*********************
AT SELECTION-SCREEN.
*-- Activate trace/debug?
IF S_Break = YES. BREAK-POINT. ENDIF.
*-- User pressed the continue or exit button?
g_RunWhat = SY-UCOMM.
CASE g_RunWhat.
WHEN 'ADDSOP' OR 'LNKSOP' OR 'ULKSOP' OR 'DELSOP'.
* *-- Goto START-OF-SELECTION event...
SSCRFIELDS-UCOMM = 'ONLI'.
WHEN 'OK' OR 'ONLI'. "OK button or SAP F8.
* *-- Goto START-OF-SELECTION event...
SSCRFIELDS-UCOMM = 'ONLI'.
WHEN 'HELP1'.
* *-- Goto START-OF-SELECTION event...
SSCRFIELDS-UCOMM = 'ONLI'.
WHEN 'EXIT'.
LEAVE.
WHEN OTHERS.
IF SY-UCOMM IS INITIAL. "Pressed ENTER on some prompt.
* *-- Here's your chance to update something on screen.
ENDIF.
ENDCASE.


*********************[ START-OF-SELECTION ]**********************
START-OF-SELECTION.
*-- Activate trace/debug?
IF S_Break = YES. BREAK-POINT. ENDIF.
*-- What pushbutton was selected.
CASE g_RunWhat.
WHEN 'OK' OR 'ONLI' OR 'ADDSOP' OR 'LNKSOP' OR 'ULKSOP' OR 'DELSOP'.
* *-- Start the report.
PERFORM L_Main.
ENDCASE.

*********************[ START L_Main() ]**********************
FORM L_Main.

* *-- Activate trace/debug?
IF S_Break = YES. BREAK-POINT. ENDIF.

* *-- For Delete, the obj_id in the "CRM Key:" input field is not
* * used. We are going to delete whatever obj_id is in the
* * "Link Key:" prompt so store it to CRMKey and pretend it's
* * the master. This way lookups will validate it. For Link/Unlink
* * we must still validate that the master CRM Key exists.
IF g_RunWhat EQ 'DELSOP'.
S_CRMKey = S_LnkKey.
ENDIF.

* *-- Get GUID for Master-Opportunity.
PERFORM L_GetGUID USING S_CRMKey CHANGING g_MastGuid g_Ok.
CHECK g_Ok = YES.

* *-- Save Master-Opportunity info.
PERFORM L_GetOppInfo USING g_MastGuid CHANGING g_Ok.
CHECK g_Ok = YES.
* *-- Store master info and place result in header.
ith_MastHeader[] = ith_GetHEADER[].
READ TABLE ith_MastHeader INDEX 1.

* *-- What action?
CASE g_RunWhat.
WHEN 'ADDSOP'.
* *-- Create/Clone Sub-Opportunity from Master Opportunity.
PERFORM L_CreateOpp CHANGING g_Ok.
WHEN 'LNKSOP' OR 'ULKSOP'.
* *-- Link or UnLink Sub-Opportunity to Master.
PERFORM L_LinkOpp USING g_RunWhat S_CRMKey S_LnkKey CHANGING g_Ok.
WHEN 'DELSOP'.
* *-- Delete Sub-Opportunity.
PERFORM L_DeleteOpp USING S_LnkKey CHANGING g_Ok.
ENDCASE.
* CHECK g_Ok = YES.

* *-- Get Master-Opportunity info again before output
* * in case we added or linked something. If Delete
* * do NOT re-get info because we deleted it and
* * the GETDETAIL info BAPI would now fail.
IF g_RunWhat NE 'DELSOP'.
PERFORM L_ClearItabs.
PERFORM L_GetOppInfo USING ith_MastHeader-GUID CHANGING g_Ok.
ENDIF.

* *-- Diplay GUIDs, Opportunities, BAPI messages, etc.
PERFORM L_OutPut.

* *-- END Output.
WRITE: / 'END:', SY-UZEIT.

* *-- End report.
NEW-PAGE PRINT OFF.
ENDFORM.
*********************[ END L_Main() ]********************

*********************[ START L_GetGUID() ]********************
FORM L_GetGUID USING P_CRMKey CHANGING P_Guid p_Ok.

* *-- Local vars.
DATA: L_CRMKey(10) TYPE C,
L_TmpTxt3(45) TYPE C,
L_LookupMode(1) TYPE C VALUE '1'. "Tried two ways to get guid.

* *-- For SAP function CRM_ORDERADM_H_GUID_GET_OW() - if used.
DATA: ET_GuidKey TYPE CRMT_OBJECT_GUID_TAB,
EV_GuidKey TYPE CRMT_OBJECT_GUID.

* *-- For manually getting guids from table CRMD_ORDERADM_H.
DATA: BEGIN OF L_TabGuids OCCURS 0,
GUID LIKE CRMD_ORDERADM_H-GUID,
OBJECT_ID LIKE CRMD_ORDERADM_H-OBJECT_ID,
END OF L_TabGuids.

* *-- Default to YES, if error will set to NO below.
p_OK = YES.

* *-- Format CMR key. (ie: 369 must be '0000000369')
l_CRMKey = P_CRMKey.
SHIFT l_CRMKey RIGHT DELETING TRAILING SPACE.
OVERLAY l_CRMKey WITH '0000000000'.

* *-- How do you want to retrieve GUID?
CASE L_LookupMode.
WHEN '1'.
* *-- Get GUID directly from order-admin table for id.
SELECT GUID OBJECT_ID
FROM CRMD_ORDERADM_H INTO TABLE L_TabGuids
WHERE OBJECT_ID = l_CRMKey AND
OBJECT_TYPE = 'BUS2000111'. "Opportunity
IF SY-SUBRC = 0.
READ TABLE L_TabGuids INDEX 1.
P_Guid = L_TabGuids-GUID.
ELSE.
p_Ok = NO.
l_TmpTxt3 = 'was not found. Try again.'.
ENDIF.
WHEN '2'.
* *-- This function works, but it sometimes retrieves multiple GUIDs
* * for the same CRMKey/ObjID - which messes me up. Maybe there are
* * different kinds of "objects" for the same id? Thought using the
* * OBJECT_TYPE = 'BUS2000111' might work but no. Decided to use the
* * direct SELECT on CRMD_ORDERADM_H above.
* *-- Get GUID for CRM object.
CALL FUNCTION 'CRM_ORDERADM_H_GUID_GET_OW'
EXPORTING
IV_OBJECT_ID = L_CRMKey "Object ID ie: 12
IV_OBJECT_TYPE = 'BUS2000111'
IMPORTING
ET_ORDERADM_H_GUID = ET_GuidKey
EV_ORDERADM_H_GUID = EV_GuidKey
EXCEPTIONS
RECORD_NOT_FOUND = 1
OBJECT_ID_IS_NOT_UNIQUE = 2
OTHERS = 3.
IF SY-SUBRC EQ 0.
P_Guid = EV_GuidKey.
ELSE.
p_Ok = NO.
CASE SY-SUBRC.
WHEN 1.
l_TmpTxt3 = 'was not found. Try again.'.
WHEN 2.
l_TmpTxt3 = 'was not unique. Maybe linked already?'.
WHEN OTHERS.
l_TmpTxt3 = 'OTHER error msg. ???'.
ENDCASE.
ENDIF. "Failed
ENDCASE. "L_LookupMode

* *-- Display fail msg.
IF p_Ok = NO.
CALL FUNCTION 'POPUP_TO_INFORM'
EXPORTING
TITEL = 'INVALID CRM NUMBER'
TXT1 = 'CRM Number'
TXT2 = l_CRMKey
TXT3 = l_TmpTxt3.
ENDIF.
ENDFORM.
*********************[ END L_GetGUID() ]********************

*********************[ START L_GetOppInfo() ]********************
FORM L_GetOppInfo USING p_GuidKey CHANGING p_Ok.
*-- Local vars.
DATA: L_LCnt TYPE I.

*-- Local tables. (Use these if you want to examine output of
* the GET BAPI. They are not used anywhere else.)
DATA: lth_ITEM TYPE TABLE OF BAPIBUS20001_ITEM_DIS WITH HEADER LINE,
lth_TEXT TYPE TABLE OF BAPIBUS20001_TEXT_DIS WITH HEADER LINE,
lth_STATUS TYPE TABLE OF BAPIBUS20001_STATUS_DIS WITH HEADER LINE,
lth_PRODUCT TYPE TABLE OF BAPIBUS20001_PRODUCT_DIS WITH HEADER LINE,
lth_SALES TYPE TABLE OF BAPIBUS20001_SALES_DIS WITH HEADER LINE,
lth_CUSTOMER_ITEM TYPE TABLE OF BAPIBUS20001_CUSTOMER_I_DIS WITH HEADER LINE,
lth_EXTENSIONOUT TYPE TABLE OF BAPIPAREX WITH HEADER LINE,
lth_APPOINTMENT TYPE TABLE OF BAPIBUS20001_APPOINTMENT_DIS WITH HEADER LINE,
lth_SERVICE_OS TYPE TABLE OF BAPIBUS20001_SERVICE_OS_DIS WITH HEADER LINE,
lth_LISTOFRELATIONS TYPE TABLE OF BAPIRELLK WITH HEADER LINE,
lth_PRICING TYPE TABLE OF BAPIBUS20001_PRICING_DIS WITH HEADER LINE,
lth_PRICING_ITEM TYPE TABLE OF BAPIBUS20001_PRICING_ITEM_DIS WITH HEADER LINE,
lth_SCHEDULE TYPE TABLE OF BAPIBUS20001_SCHEDLIN_DIS WITH HEADER LINE,
lth_SCHEDULE_ITEM TYPE TABLE OF BAPIBUS20001_SCHEDLIN_ITEM_DIS WITH HEADER LINE,
lth_CONFIG_CFG TYPE TABLE OF BAPIBUS20001_CONFIG_CUCFG_DIS WITH HEADER LINE,
lth_CONFIG_BLB TYPE TABLE OF BAPIBUS20001_CONFIG_CUBLB_DIS WITH HEADER LINE,
lth_CONFIG_INS TYPE TABLE OF BAPIBUS20001_CONFIG_CUINS_DIS WITH HEADER LINE,
lth_CONFIG_PRT TYPE TABLE OF BAPIBUS20001_CONFIG_CUPRT_DIS WITH HEADER LINE,
lth_CONFIG_VAL TYPE TABLE OF BAPIBUS20001_CONFIG_CUVAL_DIS WITH HEADER LINE,
lth_CONFIG_VK TYPE TABLE OF BAPIBUS20001_CONFIG_CUVK_DIS WITH HEADER LINE,
lth_CONFIG_REF TYPE TABLE OF BAPIBUS20001_CONFIG_CUREF_DIS WITH HEADER LINE,
lth_LIKE_ITEM TYPE TABLE OF BAPIBUS20001_STRUCTURE_DIS WITH HEADER LINE,
lth_CUMULATED_H TYPE TABLE OF BAPIBUS20001_CUMULATED_H_DIS WITH HEADER LINE.

* *-- Initialize GUID tab.
CLEAR ith_GetGUID. REFRESH ith_GetGUID.
ith_GetGUID-GUID = p_GuidKey.
APPEND ith_GetGUID.

* *--------------[ GET OPPORTUNITY INFO ]----------------
CALL FUNCTION 'BAPI_OPPORTUNITY_GETDETAILMUL'
TABLES
GUID = ith_GetGUID "<== Global
HEADER = ith_GetHEADER "<== Global
ITEM = lth_ITEM
OPPORTUNITY = ith_GetOPP "<== Global
PARTNER = ith_GetPARTNER "<== Global
ORGANISATION = ith_GetORG "<== Global
TEXT = lth_TEXT
STATUS = lth_STATUS
PRODUCT = lth_PRODUCT
SALES = lth_SALES
CUSTOMER_HEAD = ith_GetCustH "<== Global
CUSTOMER_ITEM = lth_CUSTOMER_ITEM
EXTENSIONOUT = lth_EXTENSIONOUT
RETURN = ith_GetRETURN "<== Global
APPOINTMENT = lth_APPOINTMENT
SERVICE_OS = lth_SERVICE_OS
LISTOFRELATIONS = lth_LISTOFRELATIONS
PRICING = lth_PRICING
PRICING_ITEM = lth_PRICING_ITEM
SCHEDULE = lth_SCHEDULE
SCHEDULE_ITEM = lth_SCHEDULE_ITEM
CONFIG_CFG = lth_CONFIG_CFG
CONFIG_BLB = lth_CONFIG_BLB
CONFIG_INS = lth_CONFIG_INS
CONFIG_PRT = lth_CONFIG_PRT
CONFIG_VAL = lth_CONFIG_VAL
CONFIG_VK = lth_CONFIG_VK
CONFIG_REF = lth_CONFIG_REF
LIKE_ITEM = lth_LIKE_ITEM
CUMULATED_H = lth_CUMULATED_H
DOC_FLOW = ith_GetDOCFLOW. "<== Global

* *-- Check header for results.
DESCRIBE TABLE ith_GetHEADER LINES L_LCnt.
IF L_LCnt > 0.
p_Ok = YES.
ELSE.
MESSAGE i000(crm0) WITH 'Error retrieving header for GUID.'.
p_Ok = NO.
ENDIF.

ENDFORM.
********************[ END L_GetOppInfo() ]*********************

********************[ START L_CreateOpp() ]*********************
FORM L_CreateOpp CHANGING p_OK.
* *-- Local vars.
DATA: L_Answer(1) TYPE C,
lth_Text LIKE TLINE OCCURS 0,
l_TmpDesc LIKE BAPIBUS20001_HEADER_INS-DESCRIPTION. "C(40)

* *-- Default this.
p_OK = YES.

* *-- Prompt user.
CALL FUNCTION 'POPUP_TO_CONFIRM_STEP'
EXPORTING
* DEFAULTOPTION = 'Y'
TEXTLINE1 = 'Ready to CREATE Opportunity?'
* TEXTLINE2 =
TITEL = 'CREATE OPPORTUNITY'
CANCEL_DISPLAY = ' ' "Hide the CANCEL button
IMPORTING
ANSWER = L_Answer.
IF L_Answer <> 'J'.
p_Ok = NO.
EXIT.
ENDIF.

* *-- Activate trace/debug?
IF S_Break = YES. BREAK-POINT. ENDIF.

* *---------------[ RE-GET MASTER OPP INFO AGAIN ]---------------
* *-- Start with all empty itabs.
PERFORM L_ClearITabs.
* *-- Get GUID for Master-Opportunity.
PERFORM L_GetGUID USING S_CRMKey CHANGING g_MastGuid p_Ok.
CHECK p_Ok = YES.
* *-- Get Master-Opportunity info.
PERFORM L_GetOppInfo USING g_MastGuid CHANGING p_Ok.
CHECK p_Ok = YES.

* *-----------[ Build BAPI Table Params ]-------------
DATA: lth_CHeader TYPE TABLE OF BAPIBUS20001_HEADER_INS WITH HEADER LINE,
lth_COpp TYPE TABLE OF BAPIBUS20001_OPPORTUNITY WITH HEADER LINE,
lth_COrg TYPE TABLE OF BAPIBUS20001_ORGMAN_INS WITH HEADER LINE,
lth_CPartner TYPE TABLE OF BAPIBUS20001_PARTNER_INS WITH HEADER LINE,
lth_CPricing TYPE TABLE OF BAPIBUS20001_PRICING WITH HEADER LINE,
lth_CCustH TYPE TABLE OF BAPIBUS20001_CUSTOMER_H WITH HEADER LINE,
lth_CFields TYPE TABLE OF BAPIBUS20001_INPUT_FIELDS WITH HEADER LINE.

* *-- Activate trace/debug?
IF S_Break = YES. BREAK-POINT. ENDIF.

* *-----------[ Build Header itab ]-------------
PERFORM L_BldCHeader TABLES lth_CHeader.

* *-----------[ Build Opportunities itab ]-------------
PERFORM L_BldCOpp TABLES lth_COpp.

* *-----------[ Build Organization itab ]-------------
PERFORM L_BldCOrg TABLES lth_COrg.

* *-----------[ Build Pricing itab ]-------------
PERFORM L_BldCPricing TABLES lth_CPricing lth_COpp.

* *-----------[ Build CustomerHead itab ]-------------
PERFORM L_BldCCustH TABLES lth_CCustH.

* *-----------[ Build Input_Fields itab ]-------------
* * Note, Partner itab is built here too.
PERFORM L_BldCFields TABLES lth_CFields lth_CPartner.

* *-- Activate trace/debug?
IF S_Break = YES. BREAK-POINT. ENDIF.

* *-----------[ CREATE NEW OPPORTUNITY ]-------------
CALL FUNCTION 'BAPI_OPPORTUNITY_CREATEMULTI'
EXPORTING
TESTRUN = ' '
TABLES
HEADER = lth_CHeader
OPPORTUNITY = lth_COpp
ORGANISATION = lth_COrg
PARTNER = lth_CPartner
* TEXT =
* PRODUCT =
PRICING = lth_CPricing "<== Needed for CURRENCY.
INPUT_FIELDS = lth_CFields
CREATED_PROCESS = ith_CreCreated
RETURN = ith_CreReturn
SAVED_PROCESS = ith_CreSaved
* ITEM =
* SCHEDULELINE =
* APPOINTMENT =
* SERVICE_OS =
* STATUS =
CUSTOMER_HEAD = lth_CCustH. "<== For SAIC detail data.
* CUSTOMER_ITEM =
* DOCUMENT_FLOW =
* PRICING_ITEM =
* CONFIG_CFG =
* CONFIG_BLB =
* CONFIG_INS =
* CONFIG_PRT =
* CONFIG_VAL =
* CONFIG_VK =
* CONFIG_REF =
* CONDITION_CREATE =
* EXTENSIONIN = .

* *-- The new Opportunity will not appear until you commit.
CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
EXPORTING
WAIT = 'X'.

ENDFORM.
********************[ END L_CreateOpp() ]*********************

********************[ START L_BldCHeader() ]*********************
FORM L_BldCHeader TABLES lth_CHeader STRUCTURE BAPIBUS20001_HEADER_INS.

* *-- Use Master header fields. Structures are different between
* * the GETDETAIL and CREATE BAPI's so we have to map.
READ TABLE ith_GetHEADER INDEX 1.
MOVE-CORRESPONDING ith_GetHEADER TO lth_CHeader.

CLEAR lth_CHeader-GUID. "Contains guid from master rec.
CLEAR lth_CHeader-OBJECT_ID. "ie: 000000369
lth_CHeader-GUID = g_BlankGuid.
lth_CHeader-HANDLE = 1. "<== Set this and NO SAVE at all unless ALL are set.
lth_CHeader-PROCESS_TYPE = 'OISU'. "ith_HEADER-PROCESS_TYPE = ZMST
lth_CHeader-BIN_RELATION_TYPE = 'MASU'.
APPEND lth_CHeader.

ENDFORM.
********************[ END L_BldCHeader() ]*********************

********************[ START L_BldCOpp() ]*********************
FORM L_BldCOpp TABLES lth_COpp STRUCTURE BAPIBUS20001_OPPORTUNITY.

*-- Local vars.
DATA: L_RHandle LIKE BAPIBUS20001_OPPORTUNITY-REF_HANDLE VALUE 1,
L_TmpC10(10) TYPE C,
L_TmpDesc2 LIKE BAPIBUS20001_OPPORTUNITY-DESCRIPTION_OPP. "C(40)

* *-- Structures are slightly different between
* * the GETDETAIL and CREATE BAPI's.
READ TABLE ith_GetOPP INDEX 1.
MOVE-CORRESPONDING ith_GetOPP TO lth_COpp.
lth_COpp-REF_HANDLE = L_RHandle. "<== Set this and NO 2nd Desc line saved unless ALL are set.
lth_COpp-REF_GUID = g_BlankGuid.
L_TmpDesc2 = S_SubOp1.
IF S_SubOp1 IS INITIAL OR S_SubOp1 CS '(Cloned from master nnn)'.
CONCATENATE S_CRMKey ')' INTO L_TmpC10.
CONCATENATE '(Cloned from master' L_TmpC10 INTO L_TmpDesc2
SEPARATED BY SPACE.
ENDIF.
lth_COpp-DESCRIPTION_OPP = l_TmpDesc2."<== 2nd line of desc.
APPEND lth_COpp.

ENDFORM.
********************[ END L_BldCOpp() ]********************

********************[ START L_BldCOrg() ]********************
FORM L_BldCOrg TABLES lth_COrg STRUCTURE BAPIBUS20001_ORGMAN_INS.
* *-- Structures are slightly different between
* * the GETDETAIL and CREATE BAPI's.
READ TABLE ith_GetORG INDEX 1.
MOVE-CORRESPONDING ith_GetORG TO lth_COrg.
CLEAR lth_COrg-REF_GUID.
lth_COrg-REF_GUID = g_BlankGuid.
lth_COrg-REF_HANDLE = 1.
APPEND lth_COrg.
ENDFORM.
********************[ END L_BldCOrg() ]********************

********************[ START L_BldCPricing() ]********************
FORM L_BldCPricing TABLES lth_CPricing STRUCTURE BAPIBUS20001_PRICING
lth_COpp STRUCTURE BAPIBUS20001_OPPORTUNITY.
* *-- Make sure opportunity info is in header.
READ TABLE lth_COpp INDEX 1.
* *-- Needed to store CURRENCY.
CLEAR lth_CPricing.
lth_CPricing-REF_HANDLE = 1.
lth_CPricing-REF_GUID = g_BlankGuid.
lth_CPricing-REF_KIND = 'A'.
lth_CPricing-CURRENCY = lth_COpp-CURRENCY.
lth_CPricing-CURRENCY_ISO = lth_COpp-CURRENCY_ISO.
APPEND lth_CPricing.
CLEAR lth_CPricing.
ENDFORM.
********************[ END L_BldCPricing() ]********************

********************[ START L_BldCCustH() ]********************
FORM L_BldCCustH TABLES lth_CCustH STRUCTURE BAPIBUS20001_CUSTOMER_H.
* *-- Structures are slightly different between
* * the GETDETAIL and CREATE BAPI's.
READ TABLE ith_GetCustH INDEX 1.
MOVE-CORRESPONDING ith_GetCustH TO lth_CCustH.
CLEAR lth_CCustH-REF_GUID.
lth_CCustH-REF_GUID = g_BlankGuid.
lth_CCustH-REF_HANDLE = 1.
APPEND lth_CCustH.
ENDFORM.
********************[ END L_BldCCustH() ]********************

********************[ START L_BldCFields() ]********************
FORM L_BldCFields TABLES lth_CFields STRUCTURE BAPIBUS20001_INPUT_FIELDS
lth_CPartner STRUCTURE BAPIBUS20001_PARTNER_INS.

* *-----------[ Admin Rec ]-----------
CLEAR lth_CFields.
lth_CFields-REF_HANDLE = 1. "<== Must be set if the others are too.
lth_CFields-REF_GUID = g_BlankGuid.
lth_CFields-OBJECTNAME = 'ORDERADM_H'.
lth_CFields-REF_KIND = ' '. "A <== No effect setting to A or leave blank.
lth_CFields-LOGICAL_KEY = '0001'.
lth_CFields-FIELDNAME = 'DESCRIPTION'.
APPEND lth_CFields.

* *-----------[ Opportunity ]-----------
CLEAR lth_CFields.
lth_CFields-REF_HANDLE = 1. "<== Must be set if the others are too.
lth_CFields-REF_GUID = g_BlankGuid.
lth_CFields-OBJECTNAME = 'OPPORT_H'.
lth_CFields-REF_KIND = 'A'.
lth_CFields-LOGICAL_KEY = '0001'.
lth_CFields-FIELDNAME = 'EXP_REVENUE'.
APPEND lth_CFields.

lth_CFields-FIELDNAME = 'BUDGET_BP'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'CURRENCY'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'CURRENCY_ISO'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'STARTDATE'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'EXPECT_END'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'CURR_PHASE'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'PHASE_SINCE'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'PROBABILITY'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'FORECAST_REL'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'SOURCE'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'IMPORTANCE'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'SALESCYCLE'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'ADDRESS_NO'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'TYPE'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'STATUS_SINCE'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'DESCRIPTION_OPP'.
APPEND lth_CFields.

* *-- Try these to get partners. ???
lth_CFields-FIELDNAME = 'PARTNER_NUMBER'.
APPEND lth_CFields.

* *-----------[ Organisation ]-----------
CLEAR lth_CFields.
lth_CFields-REF_HANDLE = 1. "<== Must be set if the others are too.
lth_CFields-REF_GUID = g_BlankGuid.
lth_CFields-OBJECTNAME = 'ORGMAN'.
lth_CFields-REF_KIND = 'A'.
lth_CFields-LOGICAL_KEY = '0001'. "'0006'.
lth_CFields-FIELDNAME = 'DIS_CHANNEL'.
lth_CFields-CHANGEABLE = ' '. "X = ???
APPEND lth_CFields.

* lth_CFields-FIELDNAME = 'DIS_CHANNEL_ORI'.
* APPEND lth_CFields.
lth_CFields-FIELDNAME = 'DIVISION'.
APPEND lth_CFields.
* lth_CFields-FIELDNAME = 'DIVISION_ORI'.
* APPEND lth_CFields.
lth_CFields-FIELDNAME = 'SALES_GROUP'.
APPEND lth_CFields.
* lth_CFields-FIELDNAME = 'SALES_GROUP_ORI'.
* APPEND lth_CFields.
* lth_CFields-FIELDNAME = 'SALES_GROUP_SHORT'.
* APPEND lth_CFields.
lth_CFields-FIELDNAME = 'SALES_OFFICE'.
APPEND lth_CFields.
* lth_CFields-FIELDNAME = 'SALES_OFFICE_SHORT'.
* APPEND lth_CFields.
* lth_CFields-FIELDNAME = 'SALES_OFF_ORI'.
* APPEND lth_CFields.
lth_CFields-FIELDNAME = 'SALES_ORG'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'SALES_ORGR_ORI'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'SALES_ORG_ORI'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'SALES_ORG_RESP'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'SALES_ORG_RESP_SHORT'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'SALES_ORG_SHORT'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'SERVICE_ORG_RESP'.
APPEND lth_CFields.

lth_CFields-FIELDNAME = 'SERVICE_ORG'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'DISTRICT'.
APPEND lth_CFields.
* lth_CFields-FIELDNAME = 'MODE'.
* APPEND lth_CFields.

* *-----------[ Partner info ]-----------
DATA:L_PRHandle LIKE BAPIBUS20001_PARTNER_INS-REF_HANDLE VALUE 1,
L_PRPHandle LIKE BAPIBUS20001_PARTNER_INS-REF_PARTNER_HANDLE VALUE 1.

LOOP AT ith_GetPARTNER.

* *-- Create one new partner rec for the BAPI.
MOVE-CORRESPONDING ith_GetPARTNER TO lth_CPartner.

CLEAR lth_CPartner-REF_GUID. "<== No effect either way.
CLEAR lth_CPartner-REF_HANDLE.
CLEAR lth_CPartner-REF_PARTNER_HANDLE.
CLEAR lth_CPartner-REF_PARTNER_FCT.
CLEAR lth_CPartner-REF_PARTNER_NO.
CLEAR lth_CPartner-REF_NO_TYPE.
CLEAR lth_CPartner-REF_DISPLAY_TYPE.
CLEAR lth_CPartner-MAINPARTNER.
CLEAR lth_CPartner-RELATION_PARTNER.
CLEAR lth_CPartner-BUSINESSPARTNERGUID.

* lth_CPartner-MAINPARTNER = 'X'.
lth_CPartner-REF_GUID = g_BlankGuid.
lth_CPartner-REF_HANDLE = L_PRHandle.
lth_CPartner-REF_PARTNER_HANDLE = L_PRPHandle.
APPEND lth_CPartner.

* *-- Create block of new input_fields for this partner.
CLEAR lth_CFields.
lth_CFields-REF_HANDLE = 1. "<== Must be set if the others are too.
lth_CFields-REF_GUID = g_BlankGuid.
lth_CFields-OBJECTNAME = 'PARTNER'.
lth_CFields-REF_KIND = 'A'.
lth_CFields-LOGICAL_KEY = L_PRPHandle. "ie: '0001'.
lth_CFields-FIELDNAME = 'DISPLAY_TYPE'.
lth_CFields-CHANGEABLE = ' '.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'KIND_OF_ENTRY'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'NO_TYPE'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'PARTNER_FCT'.
APPEND lth_CFields.
lth_CFields-FIELDNAME = 'PARTNER_NO'.
APPEND lth_CFields.

* *-- Inc ref-handles.
* L_PRHandle = L_PRHandle + 1. "<== Do NOT increment. (Unless creating multiple opps)
L_PRPHandle = L_PRPHandle + 1. "<== Import to link partners to CFields.
ENDLOOP.

* *-----------[ Pricing Rec]-----------
CLEAR lth_CFields.
lth_CFields-REF_HANDLE = 1. "<== Must be set if the others are too.
lth_CFields-REF_GUID = g_BlankGuid.
lth_CFields-OBJECTNAME = 'PRICING'.
lth_CFields-REF_KIND = 'A'. "A <== No effect setting to A or leave blank.
lth_CFields-LOGICAL_KEY = '0001'.
lth_CFields-FIELDNAME = 'CURRENCY'.
APPEND lth_CFields.

* *---------[ CustomerHead Rec]---------
CLEAR lth_CFields.
lth_CFields-REF_HANDLE = 1. "<== Must be set if the others are too.
lth_CFields-REF_GUID = g_BlankGuid.
lth_CFields-OBJECTNAME = 'CUSTOMER_H'.
lth_CFields-REF_KIND = 'A'. "A <== No effect setting to A or leave blank.
lth_CFields-LOGICAL_KEY = '0001'.
* *-- Get all custom fields.
DATA: LTH_FieldTab TYPE TABLE OF DFIES WITH HEADER LINE.
CALL FUNCTION 'GET_FIELDTAB_REMOTE'
EXPORTING
TABNAME = 'CRMD_CUSTOMER_H'
TABLES
FIELDTAB = LTH_FieldTab.
* *-- Add only custom fields to input-fields list.
LOOP AT LTH_FieldTab FROM 5.
lth_CFields-FIELDNAME = LTH_FieldTab-FieldName.
APPEND lth_CFields.
ENDLOOP.

ENDFORM.
********************[ END L_BldCFields() ]********************

*********************[ START L_LinkOpp() ]********************
FORM L_LinkOpp USING p_Mode p_CRMKey p_LinkKey CHANGING p_Ok.

* *-- Local vars.
DATA: L_MastGuid TYPE CRMT_OBJECT_GUID,
L_LinkGuid TYPE CRMT_OBJECT_GUID,
L_CheckOk(1) TYPE C VALUE YES,
L_TryAgain(1) TYPE C VALUE NO.

* *-- Default this.
p_OK = YES.

* *-- Activate trace/debug?
IF S_Break = YES. BREAK-POINT. ENDIF.

* *-- Get GUID for Master-Opportunity.
PERFORM L_GetGUID USING p_CRMKey CHANGING L_MastGuid p_Ok.
CHECK p_Ok = YES.

* *-- Get GUID for Sub-Opportunity.
PERFORM L_GetGUID USING p_LinkKey CHANGING L_LinkGuid p_Ok.
CHECK p_Ok = YES.

* *-----------[ Build BAPI Table Params ]-------------
DATA: lth_CHeader TYPE TABLE OF BAPIBUS20001_HEADER_UPD WITH HEADER LINE,
lth_CDFlow TYPE TABLE OF BAPIBUS20001_DOC_FLOW_INS WITH HEADER LINE,
lth_CFields TYPE TABLE OF BAPIBUS20001_INPUT_FIELDS WITH HEADER LINE.

* *----------------[ HEAD INFO ]--------------
READ TABLE ith_GetHEADER INDEX 1. "<== Header info from Master.
MOVE-CORRESPONDING ith_GetHEADER TO lth_CHeader.
APPEND lth_CHeader.

* *----------------[ INPUT FIELDS ]--------------
CLEAR lth_CFields.
lth_CFields-REF_HANDLE = 1.
lth_CFields-REF_GUID = l_MastGuid. "Master Opp.
lth_CFields-REF_KIND = 'A'.
lth_CFields-OBJECTNAME = 'DOC_FLOW'.
lth_CFields-LOGICAL_KEY = 'INS'. "<== Default to ADD.
* *-- Delete (UnLink) works in conjunction with
* * lth_CDFlow-BREL_MODE = 'D' set below.
IF p_Mode = 'ULKSOP'.
lth_CFields-LOGICAL_KEY = 'DEL'.
ENDIF.
APPEND lth_CFields.

* *---------------[ DOCUMENT FLOW ]--------------
* *-- Maybe start with original doc-flow data from Master?
READ TABLE ith_GetDOCFLOW INDEX 1.
MOVE-CORRESPONDING ith_GetDOCFLOW TO lth_CDFlow.

lth_CDFlow-REF_GUID = l_MastGuid. "Master Opp.
lth_CDFlow-REF_HANDLE = '1'.
lth_CDFlow-REF_KIND = 'A'.
lth_CDFlow-OBJKEY_A = l_MastGuid. "Master Opp.
lth_CDFlow-OBJTYPE_A = 'BUS2000111'.
* lth_CDFlow-LOGSYS_A
lth_CDFlow-OBJKEY_B = l_LinkGuid. "Sub Opp.
lth_CDFlow-OBJTYPE_B = 'BUS2000111'.
* lth_CDFlow-LOGSYS_B
lth_CDFlow-RELTYPE = 'MASU'.
* lth_CDFlow-VONA_KIND
lth_CDFlow-BREL_KIND = 'A'.
lth_CDFlow-BREL_MODE = 'A'. "A=add, B or C=Change ?, D=Del
* *-- Delete (UnLink) works in conjunction with
* * lth_CFields-LOGICAL_KEY = 'DEL' set above.
IF p_Mode = 'ULKSOP'.
lth_CDFlow-BREL_MODE = 'D'.
ENDIF.
* lth_CDFlow-HANDLE_A
* lth_CDFlow-HANDLE_B
CLEAR lth_CDFlow-RELATIONID. "<== Was preventing me from linking multi...
lth_CDFlow-RELATION_HANDLE = 1.
APPEND lth_CDFlow.

* *-- Activate trace/debug?
IF S_Break = YES. BREAK-POINT. ENDIF.

* *-- If user has Master GUID open in EDIT mode, the
* * BAPI will fail to LINK the new sub-opp.
DO.

* *-- Clear these every try.
CLEAR ith_ChgReturn. REFRESH ith_ChgReturn.

* *-----------[ CHANGE/LINK OPPORTUNITY ]----------
CALL FUNCTION 'BAPI_OPPORTUNITY_CHANGEMULTI'
EXPORTING
TESTRUN = ' '
TABLES
HEADER = lth_CHeader
* ITEM =
* OPPORTUNITY =
* ORGANISATION =
* PRICING =
* PARTNER =
* TEXT =
* PRODUCT =
* STATUS =
* SERVICE_OS =
INPUT_FIELDS = lth_CFields
RETURN = ith_ChgReturn
* APPOINTMENT =
* SCHEDULELINE =
DOCUMENT_FLOW = lth_CDFlow.
* PRICING_ITEM =
* CONDITION_CREATE =
* CONDITION_CHANGE =
* CONDITION_DELETE =.

* *-- Changes will not appear until you commit.
CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
EXPORTING
WAIT = 'X'.

* *-- Check if we need to try again.
PERFORM L_CheckOpen TABLES ith_ChgReturn CHANGING L_CheckOk L_TryAgain.
IF L_TryAgain = NO. EXIT. ENDIF.

ENDDO. "Repeat if needed.
* *-- If Check failed, return... (p_Ok was defaulted YES at top.)
IF L_CheckOk = NO. p_Ok = NO. ENDIF.
ENDFORM.
*********************[ END L_LinkOpp() ]********************

********************[ START L_CheckOpen() ]********************
FORM L_CheckOpen TABLES pt_BAPIReturn STRUCTURE BAPIRET2
CHANGING p_CheckOk p_TryAgain.

* *-- Local vars.
DATA: L_Cont(1) TYPE C,
L_IDOpen(1) TYPE C VALUE NO,
L_Saved(1) TYPE C VALUE YES,
L_OpenMsg LIKE BAPIRET2-MESSAGE. "C(220)

* *-- Default the params. ("Blank=NO, X=YES.)
p_CheckOk = YES.
p_TryAgain = NO.

* *-- Look for msg that order was open.
* * NUMBER MESSAGE C(220)
* * ie: 013 |Transaction 50 is being processed by user CUTCHALLJ
* * ie: 037 |The document could not be saved
LOOP AT pt_BAPIReturn.
* *-- Order was open.
IF pt_BAPIReturn-NUMBER = 13.
L_IDOpen = YES.
L_OpenMsg = pt_BAPIReturn-MESSAGE.
* EXIT.
ENDIF.
* *-- Could NOT be saved.
IF pt_BAPIReturn-NUMBER = 37.
L_Saved = NO.
ENDIF.
ENDLOOP.

* *-- If it was OPEN, ask user if they want to try again.
IF L_IDOpen = YES.

p_CheckOk = NO.
CONCATENATE L_OpenMsg 'Try again?' INTO L_OpenMsg SEPARATED BY SPACE.

* *-- Ask user to try again.
CALL FUNCTION 'POPUP_TO_CONFIRM'
EXPORTING
TITLEBAR = 'ERROR'
* DIAGNOSE_OBJECT = ' '
TEXT_QUESTION = L_OpenMsg
TEXT_BUTTON_1 = 'Yes'
* ICON_BUTTON_1 = ' '
TEXT_BUTTON_2 = 'No'
* ICON_BUTTON_2 = ' '
* DEFAULT_BUTTON = '1'
DISPLAY_CANCEL_BUTTON = ' '
* USERDEFINED_F1_HELP = ' '
* START_COLUMN = 25
* START_ROW = 6
* POPUP_TYPE =
* IV_QUICKINFO_BUTTON_1 = ' '
* IV_QUICKINFO_BUTTON_2 = ' '
IMPORTING
ANSWER = L_Cont.
* TABLES
* PARAMETER =
* EXCEPTIONS
* TEXT_NOT_FOUND = 1
* OTHERS = 2

* *-- Return param to stay in DO loop.
IF L_Cont EQ '1'.
p_TryAgain = YES.
ENDIF. "L_Cont
ELSE.
* *-- Item was NOT saved but has nothing to do with OPEN.
IF L_Saved = NO.
p_CheckOk = NO.
ENDIF. "L_Saved
ENDIF. "L_IDOpen = YES.
ENDFORM.
********************[ END L_CheckOpen() ]********************

*********************[ START L_DeleteOpp() ]********************
FORM L_DeleteOpp USING p_LinkKey CHANGING p_Ok.
* *-- Local vars.
DATA: L_Answer(1) TYPE C.

CLEAR p_OK.

* *-- Prompt user.
CALL FUNCTION 'POPUP_TO_CONFIRM_STEP'
EXPORTING
* DEFAULTOPTION = 'Y'
TEXTLINE1 = 'Ready to DELETE Opportunity?'
TEXTLINE2 = p_LinkKey
TITEL = 'DELETE OPPORTUNITY'
CANCEL_DISPLAY = ' ' "Hide the CANCEL button
IMPORTING
ANSWER = L_Answer.
IF L_Answer <> 'J'.
p_Ok = NO.
EXIT.
ENDIF.

* *-- Local vars.
DATA: L_LinkGuid TYPE CRMT_OBJECT_GUID,
L_CheckOk(1) TYPE C VALUE YES,
L_TryAgain(1) TYPE C VALUE NO.

* *-- Table used by the DELETE BAPI.
DATA: LTH_Obj2Del TYPE TABLE OF BAPIBUS20001_GUID_DIS WITH HEADER LINE.

* *-- Default these.
p_Ok = YES.

* *-- Global itabs used for output purposes.
CLEAR ith_DelObjs. REFRESH ith_DelObjs.
CLEAR ith_DelReturn. REFRESH ith_DelReturn.

* *-- Activate trace/debug?
IF S_Break = YES. BREAK-POINT. ENDIF.

* *-- Get GUID for Sub-Opportunity.
PERFORM L_GetGUID USING p_LinkKey CHANGING L_LinkGuid p_Ok.
CHECK p_Ok = YES.

* *-- Build list of GUIDs to delete. (Of course, there's only one here.)
LTH_Obj2Del-GUID = L_LinkGuid.
APPEND LTH_Obj2Del.

* *-- If user has Master GUID open in EDIT mode, the
* * BAPI will fail to delete the sub-opp.
DO.

* *-- Clear these return itabs every loop.
CLEAR ith_DelObjs. REFRESH ith_DelObjs.
CLEAR ith_DelReturn. REFRESH ith_DelReturn.

* *-- Delete the opportunity. (Note, I tested with a opp that was
* * linked to a master and had no problem. In other words, I did
* * not need to UN-LINK the sub-opp before deleting.)
CALL FUNCTION 'BAPI_OPPORTUNITY_DELETEMULTI'
* EXPORTING
* UPDATE_TASK_LOCAL = FALSE
TABLES
OBJECTS_TO_DELETE = LTH_Obj2Del
DELETED_OBJECTS = ith_DelObjs
RETURN = ith_DelReturn.

* *-- Changes will not appear until you commit.
CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
EXPORTING
WAIT = 'X'.

* *-- Check if we need to try again.
PERFORM L_CheckOpen TABLES ith_DelReturn CHANGING L_CheckOk L_TryAgain.
IF L_TryAgain = NO. EXIT. ENDIF.

ENDDO. "Repeat if needed.
* *-- If Check failed, return... (p_Ok was defaulted YES at top.)
IF L_CheckOk = NO. p_Ok = NO. ENDIF.
ENDFORM.
*********************[ END L_DeleteOpp() ]********************

********************[ START L_OutPut() ]********************
FORM L_OutPut.
* *-- Local vars.
DATA: L_TmpC16a(16) TYPE C,
L_TmpC16b(16) TYPE C.

* *-- Output Master GUID.
SKIP 2.
WRITE: 'Program:', SY-REPID.

* *-- Display Master GUID(s).
SKIP 1.
WRITE 'MASTER GUID:'.
LOOP AT ith_MastHeader.
WRITE: AT /5 ith_MastHeader-GUID,
ith_MastHeader-OBJECT_ID COLOR COL_HEADING,
ith_MastHeader-DESCRIPTION.
ENDLOOP.
SKIP 1.

* *-- Display Sub-Opportunities.
PERFORM L_DispSubOpps.

* *-- Output Pricing.
SKIP 1.
WRITE 'PRICING: EXPECTED BUDGET PROSPECT'.
LOOP AT ith_GetOPP.
WRITE ith_GetOPP-EXP_REVENUE DECIMALS 2 TO L_TmpC16a.
WRITE ith_GetOPP-BUDGET_BP DECIMALS 2 TO L_TmpC16b.
WRITE: AT /15 L_TmpC16a,
L_TmpC16b,
ith_GetOPP-DESCRIPTION_OPP.
ENDLOOP.

* *------------------[ GET-INFO]------------------
* *-- BAPI GET-INFO messages. (If any.)
IF NOT ith_GetReturn[] IS INITIAL.
SKIP 1.
WRITE: 'BAPI GETINFO RETURN MESSAGES:'.
LOOP AT ith_GetReturn.
WRITE: AT /5 ith_GetReturn-TYPE,
ith_GetReturn-ID,
ith_GetReturn-NUMBER,
ith_GetReturn-MESSAGE(65) COLOR COL_TOTAL. "C(220)
ENDLOOP.
ENDIF. "Not initial.

* *------------------[ CREATED ]------------------
IF g_RunWhat = 'ADDSOP'.
* *-- Saved Processes.
SKIP 1.
WRITE: 'BAPI CREATED SAVED PROCESSES:'.
LOOP AT ith_CreSaved.
WRITE: AT /5 ith_CreSaved-GUID,
ith_CreSaved-OBJECT_ID COLOR COL_GROUP.
ENDLOOP.
* *-- Created Processes.
SKIP 1.
WRITE: 'BAPI CREATED PROCESSES:'.
LOOP AT ith_CreCreated.
WRITE: AT /5 ith_CreCreated-GUID,
ith_CreCreated-PROCESS_TYPE,
ith_CreCreated-DESCRIPTION.
ENDLOOP.
* *-- Created messages.
SKIP 1.
WRITE: 'BAPI CREATED RETURN MESSAGES:'.
LOOP AT ith_CreReturn.
WRITE: AT /5 ith_CreReturn-TYPE,
ith_CreReturn-ID,
ith_CreReturn-NUMBER,
ith_CreReturn-MESSAGE(65) COLOR COL_TOTAL. "C(220)
ENDLOOP.
ENDIF. " ADDSOP

* *------------------[ CHANGED ]------------------
IF g_RunWhat = 'LNKSOP' OR g_RunWhat = 'ULKSOP'.
* *-- Changed messages.
SKIP 1.
WRITE: 'BAPI CHANGE RETURN MESSAGES:'.
LOOP AT ith_ChgReturn.
WRITE: AT /5 ith_ChgReturn-TYPE,
ith_ChgReturn-ID,
ith_ChgReturn-NUMBER,
ith_ChgReturn-MESSAGE(65) COLOR COL_TOTAL. "C(220)
ENDLOOP.
ENDIF. "LNKSOP OR ULKSOP


* *------------------[ DELETED ]------------------
IF g_RunWhat = 'DELSOP'.
* *-- Deleted objects.
SKIP 1.
WRITE: 'BAPI DELETED OBJECTS MESSAGES:'.
LOOP AT ith_DelObjs.
WRITE: AT /5 ith_DelObjs-GUID,
ith_DelObjs-OBJECT_ID COLOR COL_NEGATIVE.
ENDLOOP.
* *-- Deleted messages.
SKIP 1.
WRITE: 'BAPI DELETE RETURN MESSAGES:'.
LOOP AT ith_DelReturn.
WRITE: AT /5 ith_DelReturn-TYPE,
ith_DelReturn-ID,
ith_DelReturn-NUMBER,
ith_DelReturn-MESSAGE(65) COLOR COL_TOTAL. "C(220)
ENDLOOP.
ENDIF. "DELSOP
SKIP 1.

ENDFORM.
********************[ END L_OutPut() ]********************

********************[ START L_DispSubOpps() ]********************
FORM L_DispSubOpps.

* *-- Need local copies of these to save original doc-flow from master.
DATA: lth_DOC_FLOW2 LIKE BAPIBUS20001_DOC_FLOW_DIS OCCURS 1 WITH HEADER LINE.
* *-- Store sub-opportunities here.
DATA: BEGIN OF lth_SubOpps OCCURS 0,
Guid LIKE BAPIBUS20001_HEADER_DIS-GUID,
Object_ID LIKE BAPIBUS20001_HEADER_DIS-Object_ID,
Description LIKE BAPIBUS20001_HEADER_DIS-Description,
END OF lth_SubOpps.

* *-- Activate trace/debug?
IF S_Break = YES. BREAK-POINT. ENDIF.

* *---------------[ GET SUB OPPORTUNITIES ]-----------------
* *-- Get sub-opportunities from Doc_Flow.
lth_DOC_FLOW2[] = ith_GetDOCFLOW[].
LOOP AT lth_DOC_FLOW2 WHERE RELTYPE = 'MASU'.

* *-- Empty these each pass.
CLEAR ith_GetHEADER. REFRESH ith_GetHEADER.

* *-- Prepare to get next subopportunity from doc-flow.
CLEAR ith_GetGUID. REFRESH ith_GetGUID.
ith_GetGUID-Guid = lth_DOC_FLOW2-OBJKEY_B.
APPEND ith_GetGUID.

* *-- Get SUB-Oportunities.
CALL FUNCTION 'BAPI_OPPORTUNITY_GETDETAILMUL'
TABLES
GUID = ith_GetGUID
HEADER = ith_GetHEADER
OPPORTUNITY = ith_GetOPP. "<== Appended for price output.

* *-- Store sub-opp guid, #, desc.
IF SY-SUBRC = 0.
LOOP AT ith_GetHEADER.
lth_SubOpps-Guid = ith_GetGUID-Guid.
lth_SubOpps-Object_ID = ith_GetHEADER-Object_ID.
lth_SubOpps-Description = ith_GetHEADER-Description.
APPEND lth_SubOpps.
CLEAR lth_SubOpps.
ENDLOOP.
ENDIF.

ENDLOOP. "End getting sub-opportunity # & descrition.

* *-- Output Sub-Opportunities.
SKIP 1.
WRITE 'SUB-OPPS FROM HEADER TABLE:'.
SORT lth_SubOpps BY Object_ID.
LOOP AT lth_SubOpps.
WRITE: AT /5 lth_SubOpps-Guid,
lth_SubOpps-Object_ID COLOR COL_POSITIVE,
lth_SubOpps-Description.
ENDLOOP.
SKIP 1.
ENDFORM.
********************[ END L_DispSubOpps() ]********************

********************[ START L_ClearITabs() ]********************
FORM L_ClearITabs.

* *-- ITABs.
CLEAR: ith_GetGUID,
ith_GetHEADER,
ith_GetORG,
ith_GetPARTNER,
ith_GetOPP,
ith_GetCustH,
ith_GetDOCFLOW.
REFRESH: ith_GetGUID,
ith_GetHEADER,
ith_GetORG,
ith_GetPARTNER,
ith_GetOPP,
ith_GetCustH,
ith_GetDOCFLOW.
ENDFORM.
********************[ END L_ClearITabs() ]********************

********************[ END ZJRC_CRMBAPI01 ]********************
Back to top
View user's profile Send private message
Display posts from previous:   
Post new topic   Reply to topic    Russian ABAP Developer's Club Forum Index -> SAP Other All times are GMT + 4 Hours
Page 1 of 1

 
Jump to:  
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum
You cannot attach files in this forum
You cannot download files in this forum


All product names are trademarks of their respective companies. SAPNET.RU websites are in no way affiliated with SAP AG.
SAP, SAP R/3, R/3 software, mySAP, ABAP, BAPI, xApps, SAP NetWeaver and any other are registered trademarks of SAP AG.
Every effort is made to ensure content integrity. Use information on this site at your own risk.