Posted: Wed Dec 17, 2008 5:55 pm Post subject: Средство поиска
Подскажите каким образом при создании элементарного средства поиска создать параметр, который бы подставлял знак больше либо равно к значению по умолчанию вместо знака равенства?
Я создаю это элементарное средство поиска для включения в комплексное средство, для выборки данных в качестве метода выбора используется ракурс базы, хотелось бы чтобы передавался знак больше-равно вместо равенства
Age: 145 Joined: 04 Oct 2007 Posts: 1218 Location: Санкт-Петербург
Posted: Thu Dec 18, 2008 11:03 am Post subject:
Подумайте в таком направлении:
1) Скопируйте ФМ F4IF_SHLP_EXIT_EXAMPLE в ZXXX
2) Укажите ФМ ZXXX в поле ПользовСредсПоиска
3) Поищите по форуму примеры по слову SHLP_DESCR_T
Search Help Exit Изменение значений экрана с использованием Search-Help
4) В примерах ищите, как меняется параметр shlp-selopt
и вставьте или измените ограничения по вашим требованиям в ФМ ZXXX, например:
Code:
IF callcontrol-step = 'PRESEL'.
DATA: w_selopt LIKE LINE OF shlp-selopt.
w_selopt-sign = 'I'.
w_selopt-option = 'NE'.
w_selopt-shlpfield = 'WERKS'.
w_selopt-low = 'RU04'.
APPEND w_selopt TO shlp-selopt.
EXIT.
ENDIF.
Age: 45 Joined: 05 Nov 2007 Posts: 725 Location: КраснАдар
Posted: Thu Dec 18, 2008 11:26 am Post subject:
Без пользовательского СП не обойтись, я думаю.
1. Нужно скопировать любой F4IF_SHLP_EXIT_* функциональный модуль в Z-область.
2. В событии SELONE (before selection screen) нужно найти все поля с предопределенными значениями в таблице SHLP_TAB, для них заполнить критерии SELECT-OPTIONS и почистить, собственно, эти найденные дефолтные значения.
Пример ФМ:
Code:
FUNCTION zjdtest_shlp_exit.
*"----------------------------------------------------------------------
*"*"Локальный интерфейс:
*" TABLES
*" SHLP_TAB TYPE SHLP_DESCR_TAB_T
*" RECORD_TAB STRUCTURE SEAHLPRES
*" CHANGING
*" VALUE(SHLP) TYPE SHLP_DESCR_T
*" VALUE(CALLCONTROL) LIKE DDSHF4CTRL STRUCTURE DDSHF4CTRL
*"----------------------------------------------------------------------
DATA: h_shlp_tab TYPE shlp_descr,
h_fieldprop TYPE ddshfprop,
h_selopt TYPE ddshselopt.
DATA: i_length TYPE i.
FIELD-SYMBOLS: <fs> TYPE ANY.
CASE callcontrol-step.
WHEN 'SELONE'. " before selection screen
READ TABLE shlp_tab INTO h_shlp_tab INDEX 1.
" Prepare all "default" values to >=
LOOP AT h_shlp_tab-fieldprop INTO h_fieldprop
WHERE defaultval NE space.
CASE h_fieldprop-defaultval(2).
WHEN 'SY'. " System variable
ASSIGN (h_fieldprop-defaultval) TO <fs>.
CHECK <fs> IS ASSIGNED.
WRITE <fs> TO h_selopt-low.
WHEN OTHERS.
REPLACE ALL OCCURRENCES OF `'`
IN h_fieldprop-defaultval WITH ``.
WRITE h_fieldprop-defaultval TO h_selopt-low .
ENDCASE.
" Add criteria to range
h_selopt-shlpname = h_shlp_tab-shlpname.
h_selopt-shlpfield = h_fieldprop-fieldname.
h_selopt-sign = 'I'.
h_selopt-option = 'GE'.
APPEND h_selopt TO h_shlp_tab-selopt.
CLEAR h_fieldprop-defaultval.
MODIFY h_shlp_tab-fieldprop FROM h_fieldprop.
ENDLOOP.
MODIFY shlp_tab FROM h_shlp_tab INDEX 1.
WHEN 'SELECT'. " before selection
WHEN 'DISP'. " before selected data is displayed
WHEN OTHERS.
ENDCASE.
You cannot post new topics in this forum You cannot reply to topics in this forum You cannot edit your posts in this forum You cannot delete your posts in this forum You cannot vote in polls in this forum You cannot attach files in this forum You can download files in this forum
All product names are trademarks of their respective companies. SAPNET.RU websites are in no way affiliated with SAP AG. SAP, SAP R/3, R/3 software, mySAP, ABAP, BAPI, xApps, SAP NetWeaver and any other are registered trademarks of SAP AG. Every effort is made to ensure content integrity. Use information on this site at your own risk.
